;pdmulcp86.echo
;from pdmulcp86p6.echo, no z-period
;1.X) Program: 	multiCP/MAS at high spinning speed
;Description: 	Quantitative 13C spectra with good S/N
;Requires: 	High spinning frequency (e.g. 14 kHz)
;Reference(s):	Johnson & Schmidt-Rohr, 2013/14.
;srmulcp90p6.echo   				last CP with p6 < p5
;from srmulcp90.echo   90-100% ramps
;compare srmulcp90p6gade.180 for dipolar dephasing

;pl12 is power level for decoupling on F2

;d1 delay between scans
;d11 proton repolarization
;p5 mulcp contact time
;p6 last mulcp contact time
;p5 T1rho-filter time
;p1 X 90
;p2 X 180
;p22 X 180 for composite pulse
;p3 1H 90
;l31 MAS rate in Hz
;pl11 X 90 power level
;pl1 X CP power level

#include <Avancesolids.incl>
define delay d11d2	

	"d11d2=d11/2"
 "d13=l4*1s/l31 - p2/2-1u"  ;exactly tr from center to center of pulses
 "d3=d13-2u-de+2u" 

; "p22=1.96*p1"
  "p22=1.85*p1"


1 ze
2 d1 do:f2			;recycle delay
;#ifndef lcp15
;#include <p15_prot.incl>
			;make sure p15 does not exceed 10 msec 
			;let supervisor change this pulseprogram if 
			;more is needed
;#endif
;#ifndef lacq		
			;disable protection file for long acquisition change decoupling power !!! or you risk probe damage
			;if you set the label lacq (ZGOPTNS -Dlacq), the protection is disabled

;#include <aq_prot.incl>	
			;allows max. 50 msec acquisition time, supervisor
			;may change  to max. 1s at less than 5 % duty cycle
			;and reduced decoupling field
;#endif

  10u pl2:f2		;set 1H power level

3  d11d2 	;reset amplitude list
  p3:f2 ph11		;proton 90 pulse down
  (p1 ph10 pl3):f2 (p1 ph14 pl11):f1	;flip 13C down
  (p22 ph10):f2 (p22 ph15):f1	;flip 13C down further
  (p15 pl1 ph2):f1 (p15:sp0 ph10):f2
  (p22 ph10):f2 (p22 ph16 pl11):f1	;flip 13C down further
  (p1 ph10):f2 (p1 ph14):f1	;flip 13C up
  (p3 ph12 pl2):f2 		;proton 90 pulse up
  d11d2
  lo to 3 times l0

  d11d2
  p3:f2 ph11		;proton 90 pulse down
  (p1 ph10 pl3):f2 (p1 ph24 pl11):f1	;flip 13C down
  (p22 ph10):f2 (p22 ph25):f1	;flip 13C down further
  (p16 pl1 ph22):f1 (p16:sp0 ph10):f2

   1u cpds3:f2 pl22:f2		;high-power decoupling
    d13
  (p2 ph3 pl11):f1              ;13C 180 for Hahn echo
    d3 
  
  2u cpds2:f2 pl12:f2		;moderate-power decoupling

  go=2 ph31 		;do NS scans
  1m do:f2		;turn decoupler off
  wr #0
  exit

ph0= 0

;ph1= 1 3               ;1H 90 before last CP
ph2= 2 2 3 3 0 0 1 1     ;13C CP

ph3= 0 0 1 1 2 2 3 3   ;180 before detect (best phase for short d13)
     1 1 2 2 3 3 0 0   ;exorcycle
     2 2 3 3 0 0 1 1
     3 3 0 0 1 1 2 2 
ph4= 0			;recoupling by 180 on 1H

ph10= 2; 0                 ;1H CP
ph11= 1                 ;1H 90
ph12= 3			;1H = -ph11

ph14=     0 0 1 1 2 2 3 3   ;13C 90 onto spinlock, also all the way back up	
ph15= (8) 3 3 5 5 7 7 1 1   ;flip down further onto spinlock
ph16= (8) 5 5 7 7 1 1 3 3    ;flip up from spin lock

;ph18= 1 3 2 0 3 1 0 2    ;13C final read-out

ph22=     0 2 1 3 2 0 3 1    ;last 13C CP
ph24=     2 0 3 1 0 2 1 3    ;last 13C 90 onto spinlock, also all the way back up
ph25= (8) 7 3 1 5 3 7 5 1    ;last flip down further onto spinlock

ph31= 0 2 1 3 2 0 3 1    ;RCPH
     2 0 3 1 0 2 1 3     ;with exorcycle